Вопрос по perl, numbers – Как мне узнать, имеет ли переменная числовое значение в Perl?

77

Есть ли простой способ в Perl, который позволит мне определить, является ли данная переменная числовой? Что-то вроде:

if (is_number($x))
{ ... }

было бы идеально. Техника, которая не выдает предупреждения, когда-w переключатель используется, безусловно, предпочтительнее

Ваш Ответ

14   ответов
2

Regexp :: Общие.

Похоже, вы хотите знать, считает ли Perl переменную числовой. Вот функция, которая перехватывает это предупреждение:

sub is_number{
  my $n = shift;
  my $ret = 1;
  $SIG{"__WARN__"} = sub {$ret = 0};
  eval { my $x = $n + 1 };
  return $ret
}

Другой вариант - отключить предупреждение локально:

{
  no warnings "numeric"; # Ignore "isn't numeric" warning
  ...                    # Use a variable that might not be numeric
}

Обратите внимание, что нечисловые переменные будут автоматически преобразованы в 0, что, вероятно, в любом случае вам и нужно.

21

как определить, является ли переменная числовой, а не имеет ли она «числовое значение».

Есть несколько операторов, которые имеют отдельные режимы работы для числовых и строковых операндов, где & quot; числовые & quot; означает все, что изначально было числом или когда-либо использовалось в числовом контексте (например, в$x = "123"; 0+$xперед добавлением,$x является строкой, после чего она считается числовой).

Один из способов сказать это:

if ( length( do { no warnings "numeric"; $x & "" } ) ) {
    print "$x is numeric\n";
}
Отлично, спасибо! Это именно то, что я искал.
Проверьте это:sub numeric { my $obj = shift; no warnings "numeric"; return length($obj & ""); } print numeric("w") . "\n"; #=>0, print numeric("x") . "\n"; #=>0, print numeric("1") . "\n"; #=>0, print numeric(3) . "\n"; #=>1, print numeric("w") . "\n"; #=>1, Если вы поместите eval ('' ') вокруг длины, последний отпечаток даст 0, как и должно быть. Пойди разберись.
Если я упаковываю вашу подпрограмму в подпрограмму, я получаю странное поведение в том, что она правильно определяет нечисловые значения, пока не опробую первое числовое значение, которое также правильно определяется как истинное, но затем все остальное оттуда тоже верно. Когда я помещаю eval вокруг части length (...), она всегда работает нормально. Есть идеи, что мне не хватало?sub numeric { $obj = shift; no warnings "numeric"; return eval('length($obj & "")'); }
@yogibimbi: вы каждый раз используете одну и ту же переменную $ obj; пытатьсяmy $obj = shift;, Почему Eval?
ой, мой плохой, я использовалmy $obj = shiftконечно, просто неправильно перенес это из моего кода в комментарий, я его немного отредактировал. Тем не мение,sub numeric { my $obj = shift; no warnings "numeric"; return length($obj & ""); } выдает ту же ошибку. Конечно, наличие скрытой глобальной переменной могло бы объяснить поведение, это именно то, чего я ожидал бы в этом случае, но, к сожалению, все не так просто. Кроме того, это будет пойманstrict & Амп;warnings, Я попробовал eval в довольно отчаянной попытке избавиться от ошибки, и это сработало. Нет более глубоких рассуждений, просто пробная версия ошибка.
7

т код будет определять, является ли что-то числовым, а также проверять неопределенные переменные, чтобы не выдавать предупреждения:

sub is_integer {
   defined $_[0] && $_[0] =~ /^[+-]?\d+$/;
}

sub is_float {
   defined $_[0] && $_[0] =~ /^[+-]?\d+(\.\d+)?$/;
}

Вот некоторыематериал для чтения Вы должны посмотреть.

& APOS; .7 & APOS; Вероятно, это один из самых простых случаев, который все еще пропущен ... лучше попробуйте /^[+-]?\d*\.?\d+$/ для float. Мой вариант, учитывая научную нотацию, тоже: /^[+-]?\d*\.?\d+(?:(?:e|E)\d+)?$/
\d*\.?\d+ часть вводитReDoS риск. рекомендую/^[+-]?(?!\.(?!\d)|$)\d*(?:\.\d*)?$/ или же/^[+-]?(?!\.(?!\d)|$)\d*(?:\.\d*)?(?:(?<=[\d.])e[+-]?\d+)?$/i включить научную запись (explanation and examples) вместо Это использует двойное отрицательное предпросмотр, чтобы также предотвратить такие строки, как. а также.e0 от прохождения как числа. Он также использует позитивный взгляд заe следует за номером.
Я думаю, что это немного отвлекает, особенно когда спрашивающий сказал / просто /. Многие случаи, включая научные записи, вряд ли просты. Если бы не использовать это для модуля, я бы не стал беспокоиться о таких деталях. Иногда простота лучше. Не кладите шоколадный сироп в корову, чтобы сделать шоколадное молоко!
Это пропускает много случаев, в том числе научных обозначений.
0

что для этого нужно полагаться на внутренний контекст Perl, чтобы сделать решение пуленепробиваемым. Хорошее регулярное выражение может соответствовать всем действительным числовым значениям и ни одному из нечисловых (или наоборот), но, поскольку существует способ использовать ту же логику, которую использует интерпретатор, она должна быть более безопасной, чтобы полагаться на нее напрямую.

Как я склонен запускать свои сценарии с-wМне пришлось объединить идею сравнения результата «значение плюс ноль». к первоначальному значению сno warnings основанный на @ysth подход:

do { 
    no warnings "numeric";
    if ($x + 0 ne $x) { return "not numeric"; } else { return "numeric"; }
}
-1

    sub IS_Integer() 
    {
        my $Text = shift;
        my $Integer = 0;

        if ($Text =~ /\D/)
        {
            $Integer = 1;
        }
        if ($Text =~ /^\d+$/)
        { 
            $Integer = 1;
        }
        if ($Text =~ /^-?\d+$/)       
        { 
            $Integer = 1;
        }
        if ($Text =~ /^[+-]?\d+$/)    
        { 
            $Integer = 1; 
        }
        if ($Text =~ /^-?\d+\.?\d*$/) 
        {
            $Integer = 1; 
        }
        if ($Text =~ /^-?(?:\d+(?:\.\d*)?&\.\d+)$/) 
        {
            $Integer = 1;
        }
        if ($Text =~ /^([+-]?)(?=\d&\.\d)\d*(\,.\d*)?([Ee]([+-]?\d+))?$/)
        {
            $Integer = 1;
        }

        return $Integer;
    }
117

использованиеScalar::Util::looks_like_number() которая использует внутреннюю функцию Perl C API look_like_number (), которая, вероятно, является наиболее эффективным способом сделать это. Обратите внимание, что строки "inf" и «бесконечность»; рассматриваются как числа.

Example:
#!/usr/bin/perl

use warnings;
use strict;

use Scalar::Util qw(looks_like_number);

my @exprs = qw(1 5.25 0.001 1.3e8 foo bar 1dd inf infinity);

foreach my $expr (@exprs) {
    print "$expr is", looks_like_number($expr) ? '' : ' not', " a number\n";
}

Дает этот вывод:

1 is a number
5.25 is a number
0.001 is a number
1.3e8 is a number
foo is not a number
bar is not a number
1dd is not a number
inf is a number
infinity is a number
See also: perldoc Scalar::Util perldoc perlapi for looks_like_number
Мне нравится эта функция в целом, но рассмотрим большие целые. 1000000 - это множество нулей, за которыми нужно следить, прося ошибки, но 1,000,000 рассматривается как массив из трех элементов, поэтому Perl принимает 1_000_000, но look_like_number () говорит нет. Заставляет меня грустить.
И, как обычно, с Perl Docs, найти фактическийdefinition из того, что делает функция, довольно сложно. По следамperldoc perlapi говорит нам: Проверьте, выглядит ли содержимое SV как число (или число). & Quot; Inf & Quot; и & quot; Бесконечность & quot; обрабатываются как числа (поэтому не будут выдавать нечисловое предупреждение), даже если ваш atof () их не обманывает. Вряд ли тестируемая спецификация ...
Примечание: шестнадцатеричные строки, такие как0x12 являютсяnot считал цифры по этому тесту.
очень хорошая функция :) для неопределенных и нечисловых строк возвращает 0, для числовых строк возвращает 1, для целых возвращает 4352 и для чисел с плавающей запятой возвращает 8704 :) обычно & gt; 0 число обнаружено. Я проверил это под Linux.
С описанием в Scalar :: Util все в порядке, look_like_number сообщает вам, является ли ваш ввод чем-то, что Perl будет рассматривать как число, что не обязательно является лучшим ответом на этот вопрос. Упоминание atof не имеет значения, atof не является частью CORE :: или POSIX (вы должны смотреть на strtod, который включает atof и / is / part в POSIX) и предполагая, что то, что Perl считает числом, является допустимым числовым вводом к функциям C, очевидно, очень неправильно.
3

что для этого есть что-то встроенное. Больше, чем вы когда-либо хотели увидеть по этому вопросу, смотритеPerlmonks по обнаружению числовых

3

sub isnumber 
{
    shift =~ /^-?\d+\.?\d*$/;
}
Та же проблема, что и у ответа andrewrk: пропускает много даже простых случаев, e. г. & APOS; .7 & APOS;
1

If (($x !~ /\D/) && ($x ne "")) { ... }
1

if ( $value + 0 eq $value) {
    # A number
    push @args, $value;
} else {
    # A string
    push @args, "'$value'";
}
Например, мой $ value равен 1, $ value + 0 остается тем же 1. При сравнении с $ value 1 равен 1. Если $ value является строкой, скажите & quot; swadhi & quot; тогда $ value + 0 становится ascii значением строки "swadhi" + 0 = какой-то другой номер.
Вы должны объяснить лучше, вы говорите, что вы находите это интересным, но отвечает ли он оператору? Постарайтесь объяснить, почему ваш ответ является решением вопроса
-1

или же $ x = 0, если! $ Х; if ($ x! ~ m / \ D /) {}

Это небольшое изменение в ответе Veekay, но позвольте мне объяснить мои аргументы в пользу такого изменения.

Выполнение регулярного выражения для неопределенного значения приведет к возникновению ошибки и к выходу кода во многих, если не в большинстве сред. Проверка, определено ли значение или установка регистра по умолчанию, как я делал в альтернативном примере, перед запуском выражения, как минимум, сохранит ваш журнал ошибок.

0

чтобы определить, является ли $ foo числом (или нет).

Посмотрите здесь: Как определить, является ли скаляр числом

2

use Try::Tiny;

sub is_numeric {
  my ($x) = @_;
  my $numeric = 1;
  try {
    use warnings FATAL => qw/numeric/;
    0 + $x;
  }
  catch {
    $numeric = 0;
  };
  return $numeric;
}
23

Regexp :: Общие, Я думаю, что он делает именно то, что вам нужно, и обрабатывает все крайние случаи (например, действительные числа, научные записи и т. Д.). например

use Regexp::Common;
if ($var =~ /$RE{num}{real}/) { print q{a number}; }

Похожие вопросы