Вопрос по – Как заменить запятые пробелами в XSL

0

Мне нужно заменить каждую другую запятую пробелом в моем выводе XML. Прямо сейчас у меня есть широта и долгота, которая выглядит так:

-0.52437106918239,0.391509433962264,-0.533805031446541,0.430817610062893,0 
-0.547955974842767,0.427672955974843,

Мне нужно, чтобы координаты в моем выводе XML выглядели так:

-0.52437106918239 0.391509433962264, -0.533805031446541 0.430817610062893,0   
-0.547955974842767 0.427672955974843

Как я могу использовать XSLT для этого? Вот мой xsl:

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"    
xmlns:kml="http://www.opengis.net/kml/2.2">
<xsl:output method="text"/>

<xsl:template match="/">
<xsl:apply-templates select="kml:kml/kml:Document/kml:Placemark/kml:Polygon  
/kml:outerBoundaryIs/kml:LinearRing"/>
</xsl:template>

  <xsl:template match="kml:LinearRing">
"POLYGON((<xsl:value-of select="kml:coordinates"/>))"
 </xsl:template>
</xsl:stylesheet>

Ваш Ответ

1   ответ
1

В XSLT 2.0 это было бы тривиально. Вы могли бы использоватьзаменить ().

В XSLT 1.0 вы можете использовать шаблон так. Вызовите шаблон convert-space в вашем списке, который требует замены каждой второй запятой.

<xsl:template name="convert-space">
  <xsl:param name="text"/>
  <xsl:choose>
    <xsl:when test="contains($text,',')">
      <xsl:value-of select="substring-before($text,',')"/>
      <xsl:value-of select="' '"/>
      <xsl:call-template name="convert-comma">
        <xsl:with-param name="text" select="substring-after($text,',')"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="$text"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

<xsl:template name="convert-comma">
  <xsl:param name="text"/>
  <xsl:choose>
    <xsl:when test="contains($text,',')">
      <xsl:value-of select="substring-before($text,',')"/>
      <xsl:value-of select="','"/>
      <xsl:call-template name="convert-space">
        <xsl:with-param name="text" select="substring-after($text,',')"/>
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="$text"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

Похожие вопросы