Вопрос по – Могу ли я использовать IdUDPClient для отправки запроса M-SEARCH?

5

В моей сети мало устройств uPNP. Я пытаюсь отправить запрос M-SEARCH в сеть и надеюсь получить от него некоторые ответы. Вот что я пытаюсь:

var sIP, sOut: string;
    iPort: Word;
    S: TStringBuilder;
begin
  S := TStringBuilder.Create;
  try
    S.Append('M-SEARCH * HTTP/1.1').AppendLine
     .Append('HOST: 239.255.255.250:1900').AppendLine
     .Append('MAN: "ssdp:discover"').AppendLine
     .Append('MX: 10').AppendLine
     .Append('ST: ssdp:all').AppendLine;

    IdUDPClient1.ReceiveTimeout := 3000;
    IdUDPClient1.Broadcast(S.ToString, 1900, '239.255.255.250');
    sOut := IdUDPClient1.ReceiveString(sIP, iPort);
    Memo1.Lines.Add(sIP);
    Memo1.Lines.Add(IntToStr(iPort));
    Memo1.Lines.Add(sOut);
  finally
    S.Free;
  end;
end;

Я ничего не получаю от клиента UDP. Я использую Wireshark для мониторинга сетевого трафика, и с моего хоста не было отправлено ни одного сообщения.

Есть идеи? Спасибо.

Я наконец нашел ответ:

uses
  System.SysUtils, IdUDPClient, IdStack;

var S: TStringBuilder;
    U: TIdUDPClient;
    iPeerPort: Word;
    sPeerIP, sResponse: string;
begin
  U := TIdUDPClient.Create(nil);
  S := TStringBuilder.Create;
  try
    S.Append('M-SEARCH * HTTP/1.1').AppendLine
     .Append('HOST: 239.255.255.250:1900').AppendLine
     .Append('MAN: "ssdp:discover"').AppendLine
     .Append('MX: 3').AppendLine
     .Append('ST: ssdp:all').AppendLine
     .AppendLine;

    U.BoundIP := GStack.LocalAddress;
    U.Send('239.255.255.250', 1900, S.ToString);

    U.ReceiveTimeout := 1000;
    repeat
      sResponse := U.ReceiveString(sPeerIP, iPeerPort);
      if iPeerPort <> 0 then begin
        WriteLn(Format('%s:%d', [sPeerIP, iPeerPort]));
        WriteLn(sResponse);
      end;
    until iPeerPort = 0;
    ReadLn;
  finally
    S.Free;
    U.Free;
  end;
end.

Ваш Ответ

3   ответа
6

AppendLine() дважды в конце строителя строк. Заголовки HTTP-запроса завершаются двумя парами CRLF, но вы добавляете только одну пару, поэтому отправляете неполный запрос.

Я добавляю новый AppendLine () в объект stringbuilder, но я тоже не получил никакого ответа. Я также не заметил запрос от моего хоста при мониторинге трафика через WireShark. Chau Chee Yang
Ты уверен, что239.255.255.250 правильный широковещательный IP для вашей локальной сети? Какой локальный IP-адрес и подсеть назначен компьютеру вашего клиента? Remy Lebeau
Если я транслирую на номер 239.255.255.255, я вижу трафик, отправленный с моего хоста. Но транслировался на 239.255.255.250, трафик не был обнаружен. Chau Chee Yang
Я не уверен, должен ли 239.255.255.250 быть адресом, который я должен передать. Я пытаюсь отправить пакет m-search на номер 239.255.255.250, чтобы получить некоторые ответы от доступных устройств uPNP в моей сети. Как это сделать с IdUDPClient? Должен ли я вещать или отправлять? Chau Chee Yang
Я обнаружил проблему. Я должен установить BoundIP на IP моего адаптера. Служба хоста устройства uPNP не слушает 0.0.0.0. Он слушает только IP-адрес адаптера хоста. Chau Chee Yang
3

Удалите компонент TIdUDPServer на форму и с помощью инспектора объектов установите привязки к вашему локальному IP, например. 10.1.0.78:0, установите BroadcastEnabled и Active в значение true. Оставьте TMemo и TButton в форме.

Завершите события OnClick и UDPRead следующим образом:

uses IdSocketHandle;
...
procedure TForm1.Button1Click(Sender: TObject);
begin
  IdUDPServer1.Send('239.255.255.250', 1900, 'M-SEARCH * HTTP/1.1' + #13#10 +
     'HOST: 239.255.255.250:1900' + #13#10 +
     'MAN: "ssdp:discover"'+ #13#10 +
     'MX: 3'+ #13#10 +
     'ST: ssdp:all'+ #13#10 +
     #13#10);
end;

procedure TForm1.IdUDPServer1UDPRead(Sender: TObject; AData: TStream; ABinding: TIdSocketHandle);
var 
   data: string;
begin

   setlength(data, Adata.Size - AData.Position); //No fragmentation :)        
   AData.ReadBuffer(data[1], length(data));

   memo1.Lines.Add('Read: ' + inttostr(AData.Position) + ' / ' + inttostr(AData.Size) + ' PeerIP: ' + ABinding.PeerIP);       
   memo1.Lines.Add(data);
end;

Спасись, беги, а Боб твой дядя.

0

ия между * * являются заполнителями для фактических значений.

M-SEARCH * HTTP/1.1
HOST: 239.255.255.250:1900
MAN: "ssdp:discover"
MX: *seconds to delay response*
ST: *search target*
USER-AGENT: *OS/version UPnP/1.1 product/version*

Так что вам нужно исправить ReceiveTimeout на

U.ReceiveTimeout := 3000;

Это должно быть как минимум равно задержке в вашем запросе (MX: 3) 3 секунды = 3000 миллисекунд

Похожие вопросы